build.gradle

plugins {
    id 'java'
    id 'org.springframework.boot' version '3.2.7'
    id 'io.spring.dependency-management' version '1.1.5'
}

group = 'com.planetrush'
version = '0.0.1-SNAPSHOT'

java {
    toolchain {
        languageVersion = JavaLanguageVersion.of(21)
    }
}

configurations {
    compileOnly {
        extendsFrom annotationProcessor
    }
}

repositories {
    mavenCentral()
}

dependencyManagement {
    imports {
        /* Testcontainers BOM (Spec 001 — Constitution 원칙 I 충족 토대, Apache 2.0, 활발한 유지보수) */
        mavenBom 'org.testcontainers:testcontainers-bom:2.0.5'
    }
}

dependencies {
    /* S3 file upload */
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'

    /* QueryDSL */
    implementation 'com.querydsl:querydsl-jpa:5.0.0:jakarta'
    annotationProcessor "com.querydsl:querydsl-apt:${dependencyManagement.importedProperties['querydsl.version']}:jakarta"
    annotationProcessor "jakarta.annotation:jakarta.annotation-api"
    annotationProcessor "jakarta.persistence:jakarta.persistence-api"

    /* Spring Boot */
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-data-jpa'
    implementation 'org.springframework.security:spring-security-oauth2-client'
    implementation 'org.springframework.boot:spring-boot-starter-web'
    implementation 'org.springframework.boot:spring-boot-starter-reactor-netty'
    implementation 'org.springframework.boot:spring-boot-starter-webflux'
    implementation 'org.springframework.boot:spring-boot-starter-data-redis'
    implementation 'org.springframework.retry:spring-retry'
    implementation 'io.jsonwebtoken:jjwt-api:0.11.5'
    implementation 'org.springframework.cloud:spring-cloud-starter-aws:2.2.6.RELEASE'
    implementation 'org.springframework.boot:spring-boot-starter-cache'
    implementation 'com.github.ben-manes.caffeine:caffeine'

    /* Swagger */
    implementation group: 'org.springdoc', name: 'springdoc-openapi-starter-webmvc-ui', version: '2.4.0'

    /* Mattermost */
    implementation 'com.google.code.gson:gson:2.10.1'


    compileOnly 'org.projectlombok:lombok'
    runtimeOnly 'com.h2database:h2'
    runtimeOnly 'com.mysql:mysql-connector-j'
    runtimeOnly 'io.jsonwebtoken:jjwt-impl:0.11.5'
    runtimeOnly 'io.jsonwebtoken:jjwt-jackson:0.11.5'

    annotationProcessor 'org.projectlombok:lombok'
    testImplementation 'org.springframework.boot:spring-boot-starter-test'
    testRuntimeOnly 'org.junit.platform:junit-platform-launcher'

    /* Testcontainers (Spec 001 — 통합 테스트 자립화, 로컬 데몬 의존 제거) */
    testImplementation 'org.testcontainers:testcontainers-junit-jupiter'
    testImplementation 'org.testcontainers:testcontainers-mysql'
    testImplementation 'org.apache.commons:commons-lang3:3.18.0'
}

/* Spec 001 SC-005 — 시크릿 키워드 평문 로그 차단 게이트.
 * grep 매치 발견 시 빌드 실패. check 단계에 자동 hook. */
tasks.register('verifySecretLogScan', Exec) {
    description = 'Fail build if plaintext secret keywords are logged anywhere in src/main.'
    group = 'verification'
    workingDir project.rootDir
    commandLine 'sh', '-c',
        'if grep -RInE "log\\.(info|debug|warn)\\(.*(secret|token|password|jwt|credential).*=.*\\)" src/main; then echo "❌ Secret keyword in log statement detected (Constitution 원칙 V 위반)"; exit 1; else echo "✓ secret log scan clean"; exit 0; fi'
}
tasks.named('check') { dependsOn 'verifySecretLogScan' }

allprojects {
    tasks.withType(JavaCompile) {
        options.encoding = 'UTF-8'
    }
    tasks.withType(Javadoc) {
        options.encoding = 'UTF-8'
    }
}

tasks.named('test') {
    useJUnitPlatform()
}

clean {
    delete file('src/main/generated')
}